COMMENT ⊗   VALID 00003 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	PID DDB I J X Y Z PORT DEVICE IO%CON IO%CCR DEVNAM DEVCHR DEVIOS DPID 1PID NPIDS 2PID PIDPRG SWPBLK
C00004 00003	DLNLGR CHECK NEXT
C00006 ENDMK
C⊗;
;PID DDB I J X Y Z PORT DEVICE IO%CON IO%CCR DEVNAM DEVCHR DEVIOS DPID 1PID NPIDS 2PID PIDPRG SWPBLK

TITLE DLNLGR
SUBTTL MRC 7/79

PID==1
DDB==3
I==4
J==5
X==6
Y==7
Z==10
PORT==11
DEVICE==17

IO%CON==200
IO%CCR==400

DEVNAM==400000
DEVCHR==400001
DEVIOS==400002
DPID==400032

1PID:	.BYTE 9
	"F ? "T ? "P ?  0	; File Transfer
	"T ? "E ? "L ? "N	; TELNET
	"M ? "A ? "I ? "L	; MAIL
	.BYTE
NPIDS==.-1PID

2PID:	.BYTE 9
	 0 ?  0 ?  0 ?  0	; File Transfer
	"E ? "T ?  0 ?  0	; TELNET
	 0 ?  0 ?  0 ?  0	; MAIL
	.BYTE
IFN NPIDS-<.-2PID>,.FATAL Guess what you forgot to change

PIDPRG:	'RPCFTP			; File Transfer
	'RPCTLN			; TELNET
	'RPCMAI			; MAIL
IFN NPIDS-<.-PIDPRG>,.FATAL You bit the bag in PIDPRG

SWPBLK:	'DSK,,
	BLOCK 1
	'DMP,,14
	0
	'NETSYS
	'NETSYS
;DLNLGR CHECK NEXT

DLNLGR:	CAI
	RESET
	MOVSI 377777
	SETPR2
	 JRST 4,.-1
	MOVEI I,[.RSQZ 0,DLNUTB ? 0]
	.SYML I,
	 JRST 4,.-1
	MOVEI [.RSQZ 0,DLNNUM ? 0]
	.SYML
	 JRST 4,.-1
	MOVN
	HRL I,
	MOVSI Y,IO%CON
	MOVSI X,IO%CCR
	MOVEI PORT,"0
CHECK:	MOVE DDB,400000(I)
	TDNN Y,DEVIOS(DDB)
	 TDNN X,DEVIOS(DDB)
	  JRST NEXT
	DMOVE PID,DPID(DDB)
	SKIPN PID
	 JUMPE PID+1,NEXT
	LDB J,[360600,,DEVCHR(DDB)]
	JUMPN J,NEXT
	OUTSTR [ASCIZ/Port /]
	OUTCHR PORT
	OUTSTR [ASCIZ/, PID /]
	MOVE Z,[441100,,PID]
	MOVEI J,8.
	ILDB Z
	OUTCHR
	SOJG J,.-2
	MOVSI J,-NPIDS
	CAMN PID,1PID(J)
	 CAME PID+1,2PID(J)
	  AOBJN J,.-2
	JUMPGE J,[	OUTSTR [ASCIZ/ ***** Unknown PID *****
/]
			JRST NEXT]
	MOVE PIDPRG(J)
	MOVEM SWPBLK+1
	MOVE DEVICE,DEVNAM(DDB)
	MOVEI SWPBLK
	SWAP
	OUTSTR [ASCIZ/
/]
NEXT:	AOS PORT
	AOBJN I,CHECK
	EXIT

END DLNLGR